***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 25, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SX34 A K 
.param
+vc0 = 1.945e-1
+vc1 = 2.815e-2
+vc2 = 6.577e-3
+tc1 = 8.527e-2
+tc2 = 3.672e-2
gdiode K A value={(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d1 A K diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.5e-3   
+is = 1.661e-6
+n = 1.067
+rs = 2.787e-2
+bv = 44
+isr = 1.557e-7
+nr = 1.068
***** capacitance parameter ***
+cjo = 4.726e-10
+vj = 3.603e-1
+m = 4.369e-1
+fc = 0.5  
***** temperature coefficient ***
+tnom = 25                     
+eg = 6.392e-1
+xti = 3 
+trs1 = 6.321e-3
+trs2 = -1.233e-6
.ends SX34
*$
